| Net::DNS::Update - DNS dynamic update packet |
Net::DNS::Update - DNS dynamic update packet
use Net::DNS;
$update = new Net::DNS::Update( 'example.com', 'IN' );
$update->push( prereq => nxrrset('foo.example.com. AAAA') );
$update->push( update => rr_add('foo.example.com. 86400 AAAA 2001::DB8::1') );
Net::DNS::Update is a subclass of Net::DNS::Packet, to be used for making DNS dynamic updates.
Programmers should refer to RFC2136 for dynamic update semantics.
$update = new Net::DNS::Update;
$update = new Net::DNS::Update( 'example.com' );
$update = new Net::DNS::Update( 'example.com', 'HS' );
Returns a Net::DNS::Update object suitable for performing a DNS dynamic update. Specifically, it creates a packet with the header opcode set to UPDATE and the zone record type to SOA (per RFC 2136, Section 2.3).
Programs must use the push() method to add RRs to the prerequisite
and update sections before performing the update.
Arguments are the zone name and the class. The zone and class may be undefined or omitted and default to the default domain from the resolver configuration and IN respectively.
$ancount = $update->push( prereq => $rr );
$nscount = $update->push( update => $rr );
$arcount = $update->push( additional => $rr );
$nscount = $update->push( update => $rr1, $rr2, $rr3 );
$nscount = $update->push( update => @rr );
Adds RRs to the specified section of the update packet.
Returns the number of resource records in the specified section.
Section names may be abbreviated to the first three characters.
$ancount = $update->unique_push( prereq => $rr );
$nscount = $update->unique_push( update => $rr );
$arcount = $update->unique_push( additional => $rr );
$nscount = $update->unique_push( update => $rr1, $rr2, $rr3 );
$nscount = $update->unique_push( update => @rr );
Adds RRs to the specified section of the update packet provided that the RRs are not already present in the same section.
Returns the number of resource records in the specified section.
Section names may be abbreviated to the first three characters.
The first example below shows a complete program. Subsequent examples show only the creation of the update packet.
Although the examples are presented using the string form of RRs, the corresponding ( name => value ) form may also be used.
#!/usr/bin/perl
use Net::DNS;
# Create the update packet.
my $update = new Net::DNS::Update('example.com');
# Prerequisite is that no address records exist for the name.
$update->push( pre => nxrrset('foo.example.com. A') );
$update->push( pre => nxrrset('foo.example.com. AAAA') );
# Add two address records for the name.
$update->push( update => rr_add('foo.example.com. 86400 A 192.0.2.1') );
$update->push( update => rr_add('foo.example.com. 86400 AAAA 2001:DB8::1') );
# Send the update to the zone's primary master.
my $resolver = new Net::DNS::Resolver;
$resolver->nameservers('primary-master.example.com');
my $reply = $resolver->send($update);
# Did it work?
if ($reply) {
if ( $reply->header->rcode eq 'NOERROR' ) {
print "Update succeeded\n";
} else {
print 'Update failed: ', $reply->header->rcode, "\n";
}
} else {
print 'Update failed: ', $resolver->errorstring, "\n";
}
my $update = new Net::DNS::Update('example.com');
$update->push( prereq => yxdomain('example.com') );
$update->push( update => rr_add('example.com MX 10 mailhost.example.com') );
my $update = new Net::DNS::Update('example.com');
$update->push( prereq => nxdomain('info.example.com') );
$update->push( update => rr_add('info.example.com TXT "yabba dabba doo"') );
my $update = new Net::DNS::Update('example.com');
$update->push( prereq => yxrrset('foo.example.com A') );
$update->push( update => rr_del('foo.example.com A') );
my $update = new Net::DNS::Update('example.com');
$update->push( prereq => yxdomain('byebye.example.com') );
$update->push( update => rr_del('byebye.example.com') );
my $update = new Net::DNS::Update('example.com');
$update->push( update => rr_add('foo.example.com AAAA 2001:DB8::1') );
$update->sign_tsig( "$dir/Khmac-sha512.example.com.+165+01018.private" );
my $reply = $resolver->send( $update );
$reply->verify( $update ) || die $reply->verifyerr;
$update->sign_tsig( "$dir/Khmac-sha512.example.com.+165+01018.key" );
$update->sign_tsig( "$dir/Khmac-sha512.example.com.+165+01018.private",
fudge => 60
);
my $key_name = 'tsig-key';
my $key = 'awwLOtRfpGE+rRKF2+DEiw==';
my $tsig = new Net::DNS::RR("$key_name TSIG $key");
$tsig->fudge(60);
my $update = new Net::DNS::Update('example.com');
$update->push( update => rr_add('foo.example.com AAAA 2001:DB8::1') );
$update->push( additional => $tsig );
Copyright (c)1997-2000 Michael Fuhr.
Portions Copyright (c)2002,2003 Chris Reinhardt.
Portions Copyright (c)2015 Dick Franks.
All rights reserved.
Permission to use, copy, modify, and distribute this software and its documentation for any purpose and without fee is hereby granted, provided that the above copyright notice appear in all copies and that both that copyright notice and this permission notice appear in supporting documentation, and that the name of the author not be used in advertising or publicity pertaining to distribution of the software without specific prior written permission.
THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
the perl manpage, the Net::DNS manpage, the Net::DNS::Packet manpage, the Net::DNS::Header manpage, the Net::DNS::RR manpage, the Net::DNS::Resolver manpage, RFC 2136, RFC 2845
| Net::DNS::Update - DNS dynamic update packet |